QQ空间免费代码之自制地华丽FLASH鼠标特效

QQ空间代码站为广大Q友提供的QQ空间免费代码之自制的华丽FLASH鼠标特效，希望大家能够喜欢！以下代码经【Q人类Q生活】团队测试确定可用，目前很多网站发布的所谓“QQ空间免费代码”是伪代码是失效的，保存后虽提示成功，但刷新后就不见了，所以请各位Q友要辨别清楚，特别要注意发布日期。

下面Q人类Q生活[Qzoner]QQ空间站就教大家一个的制作免费鼠标代码效果教程，很特殊，是一些带颜色的不段变换形状的一些图形。

　　下面Qzoner说说制作方法。

　　首先新建立文档，然后按Ctrl+J修改属性。

然后在第一帧中放入下面代码。

/* 定义5个全局变量 */
var time:Number = 0;
var timeMin:Number = 100;
var alphaDrop:Number = 2;
var growBy:Number = 2;
var rotateByMax:Number = 10;

/* 转变弧度的函数 */
function deg2rad(degrees:Number):Number {
  return degrees * Math.PI / 180;
}
 
/* 返回最大值和最小值之间的一个数 */
function randRange(min:Number, max:Number):Number {
  var randomNum:Number = Math.floor(Math.random() * (max - min + 1)) + min;
  return randomNum;
}

/* 绘制规则多边形，设置颜色、大小、半径QZONER.COM */
function drawPoly(sides:Number, color:Number, radius:Number):MovieClip {
  var depth:Number = _root.getNextHighestDepth();
  var poly_mc:MovieClip = _root.createEmptyMovieClip("poly" + depth, depth);
  var unitAngle = deg2rad(360 / sides);
 
  poly_mc.beginFill(color);
  poly_mc.moveTo(radius, 0);
  for (var i:Number = 1; i < sides; i++) {
    var turn:Number = unitAngle * i;
    var dx:Number = Math.cos(turn) * radius;
    var dy:Number = Math.sin(turn) * radius;
    poly_mc.lineTo(dx, dy);
  }
  poly_mc.endFill();
 
  return poly_mc;
}

/* 初始化一个影片剪辑QZONER.COM */
function initPoly():Void {
  this._x = _xmouse;
  this._y = _ymouse;
  this._xscale = this._yscale = 0;
  this.rotateBy = randRange(-rotateByMax, rotateByMax);
 
  this.onEnterFrame = function():Void {
    this._xscale = this._yscale += growBy;
    this._alpha -= alphaDrop;
    this._rotation += this.rotateBy;
 
    if (this._alpha < 0) {
      this.removeMovieClip();
    }
  };
}

/* 主程序 */
onMouseMove = function():Void {
  if (getTimer() - time > timeMin) {
    initPoly.apply(drawPoly(randRange(3, 12), randRange(0, 0xFFFFFF), 100));
    time = getTimer();
  }
};

这样设置背景715*900，然后进入QQ空间新建QQ空间flash模块：把上面的flash存放到你的个人空间里，在这里输入得到的地址，拉到无限大，就可以免费享用自己做的鼠标代码了。